struct mousePaint (
    
    minDistance   = 12,
    delay         = 17,
    lastPaintTime = 0,
    lastPoint     = [1e5,1e5,1e5],
    
    fn mouseTrackCallback msg ir obj faceNum shift ctrl alt = (
    
        ts = timeStamp()
        
        case msg of (
                        
            #freeMove:   () -- means the mouse is moved without a button being pressed
            #mousePoint: () -- means the left mouse button has just been pressed
            #mouseMove:  (  -- means the mouse is being dragged with the left button down
                
                if ir.pos != undefined and (ts - lastPaintTime) > delay do (
            
                    lastPaintTime = ts
                    
                    if distance lastPoint ir.pos > minDistance do (
                        
                        GeoSphere pos:ir.pos
                        lastPoint = ir.pos
                        
                    )
                
                )
                
                
            )
            #mouseAbort: ( return ok ) -- means the right mouse button was clicked, normally meaning cancel
                        
        )

        
        #continue
        
    ),
    
    fn start obj: = (
        
        if obj != unsupplied then (
                        
            mouseTrack on:obj trackCallback:mouseTrackCallback
            
        ) else (
            
            mouseTrack trackCallback:mouseTrackCallback
            
        )
        
    )
)

mp = mousePaint()
if isKindOf selection[1] Editable_mesh then mp.start obj:selection[1] else mp.start()